Hardware

E-Mail-Benachrichtigungen für Dell Server-Hardwarewarnungen einrichten Alert


Alle Dell Server werden mit der Dell OpenManage Server Administrator-Software geliefert, die die Möglichkeit bietet, Indikatoren auf Systemebene zu überwachen und anzuzeigen. Darüber hinaus können Sie über die Registerkarte Warnungsverwaltung Aktionen konfigurieren, die ausgeführt werden, wenn eine Warnung ausgelöst wird. Leider gibt es kein Mittel, um einheitliche Benachrichtigungen auf alle Ereignisse anzuwenden. Daher werden wir ein Skript bereitstellen, das alle Warnaktionen so konfiguriert, dass Sie eine E-Mail über das jeweilige Ereignis senden. Sie könnten diese zwar manuell einrichten, aber ein Skript ist ideal, da Sie dies problemlos auf mehreren Servern bereitstellen können.

Wie es funktioniert

Das Skript ist sehr einfach. Es gibt einen Setup-Befehl, der jede Warnung auf „Anwendung ausführen“ setzt, wobei die Anwendung das Skript selbst ist. Wenn das Skript ausgeführt wird, generiert es einfach eine E-Mail (mithilfe des Blat-Tools) mit Computername, Datum, Uhrzeit und ausgelöster Warnung.

Bevor das Skript ausgeführt wird:

Nachdem das Skript ausgeführt wurde:

1622784808 914 E Mail Benachrichtigungen fuer Dell Server Hardwarewarnungen einrichten Alert

Alle Warnungen verwenden das E-Mail-Benachrichtigungsskript:

1622784809 734 E Mail Benachrichtigungen fuer Dell Server Hardwarewarnungen einrichten Alert

Bedarf

Natürlich muss Dell OpenManage Server Assistant installiert sein. Diese Software kann über die Support-Site von Dell heruntergeladen werden, sofern sie nicht im Lieferumfang Ihres Systems enthalten ist.

Darüber hinaus müssen Sie Blat, einen Befehlszeilen-E-Mailer, auf Ihrem System konfigurieren. Um Blat zu konfigurieren, laden Sie einfach die Binärdateien herunter und extrahieren Sie sie (insgesamt 3: blat.exe, blat.dll, blat.lib) an einen Ort in der PATH-Variablen Ihres Systems, z. Führen Sie dann von der Befehlszeile aus:

blat -installiere my.mailserver.com fromaddress@email.com

Ersetzen Sie den Mailserver und die Absender-E-Mail-Adresse entsprechend. Meistens ist dieser Befehl alles, was Sie zum Ausführen benötigen, aber wenn Ihr Server eine spezielle Konfiguration hat (alternativer Port usw.), können Sie die vollständigen Installationsoptionen auf Blats Website einsehen.

Einrichtung von E-Mail-Benachrichtigungen

Sobald Sie diese Anforderungen erfüllt haben, können Sie das Skript verwenden. Bearbeiten Sie das Skript, um die zu benachrichtigende(n) E-Mail-Adresse(n) einzuschließen (die Variable ‚ToEmail‘). Wenn Ihr Server für die Weiterleitung eine Authentifizierung erfordert, müssen Sie diese Parameter zum Blat-Befehl hinzufügen, wie im Skript dokumentiert.

Um die Server Assistant-Warnungen für die Verwendung des Skripts einzurichten, führen Sie einfach das Setup aus:

DellAlert /setup

Bestätigen Sie, dass Sie dieses Skript als Ihre Warnaktion verwenden möchten, und Sie sind fertig. Als Teil der Einrichtung wird eine Beispielwarnung ausgelöst, damit Sie sicherstellen können, dass die E-Mails die vorgesehenen Empfänger erreichen.

Das Skript

@ECHO OFF
TITLE Dell Hardware Email Alert
ECHO Dell Hardware Email Alert
ECHO Written by: Jason Faulkner
ECHO SysadminGeek.com
ECHO.
ECHO.

REM Sends email alerts when Dell hardware warnings are triggered.
REM This script should _not_ be in a path which contains spaces.
REM
REM Usage:
REM DellAlert {/SETUP | Alert message}
REM    /SETUP   Configure Dell Server Assistant to use this script for alerts.
REM    Alert Message
REM             Message to send.
REM
REM Requires:
REM Blat : (command line emailer) is configured and working on the current system.
REM        If your email server requires authentication to relay, see comments below.

REM Email address(es) to send alerts to (comma separated)
SET ToEmail=myaddress@email.com

SETLOCAL EnableExtensions

IF /I {%1}=={/SETUP} GOTO Setup
IF NOT {%1}=={} GOTO Alert
GOTO End

:Alert
SET Log="%TEMP%DellAlert.txt"

DATE /T > %Log%
TIME /T >> %Log%
ECHO Dell Alert Tripped! >> %Log%
ECHO %* >> %Log%

REM If your email server requires autentication to relay,
REM add the following to the end of the line below:
REM -u UserName -pw Password
BLAT %Log% -to %ToEmail% -subject "%ComputerName% Hardware Alert"

IF EXIST %Log% DEL /F /Q %Log%
GOTO End

:Setup
ECHO This will replace all the current Dell Server Assistant alerts with a call
ECHO to this script. To confirm you want to continue, enter YES (case sensitive).
SET /P Confirm=
IF NOT {%Confirm%}=={YES} GOTO End

SET ScriptPath=%~dpnx0
ECHO Configuring alerts to use: %ScriptPath%

omconfig system alertaction event=powersupply execappath="%ScriptPath% power supply failure"
omconfig system alertaction event=powersupplywarn execappath="%ScriptPath% power supply warning"
omconfig system alertaction event=tempwarn execappath="%ScriptPath% temperature warning"
omconfig system alertaction event=tempfail execappath="%ScriptPath% temperature failure"
omconfig system alertaction event=fanwarn execappath="%ScriptPath% fan speed warning"
omconfig system alertaction event=fanfail execappath="%ScriptPath% fan speed failure"
omconfig system alertaction event=voltwarn execappath="%ScriptPath% voltage warning"
omconfig system alertaction event=voltfail execappath="%ScriptPath% voltage failure"
omconfig system alertaction event=intrusion execappath="%ScriptPath% chassis intrusion"
omconfig system alertaction event=redundegrad execappath="%ScriptPath% redundancy degraded"
omconfig system alertaction event=redunlost execappath="%ScriptPath% redundancy lost"
omconfig system alertaction event=memprefail execappath="%ScriptPath% memory pre-failure"
omconfig system alertaction event=memfail execappath="%ScriptPath% memory failure"
omconfig system alertaction event=hardwarelogwarn execappath="%ScriptPath% hardware log warning"
omconfig system alertaction event=hardwarelogfull execappath="%ScriptPath% hardware log full"
omconfig system alertaction event=processorwarn execappath="%ScriptPath% processor warning"
omconfig system alertaction event=processorfail execappath="%ScriptPath% processor failure"
omconfig system alertaction event=watchdogasr execappath="%ScriptPath% watchdog asr"
omconfig system alertaction event=batterywarn execappath="%ScriptPath% battery warning"
omconfig system alertaction event=batteryfail execappath="%ScriptPath% battery failure"
omconfig system alertaction event=systempowerwarn execappath="%ScriptPath% system power warning"
omconfig system alertaction event=systempowerfail execappath="%ScriptPath% system power failure"

omconfig system alertaction event=storagesyswarn execappath="%ScriptPath% storage system warning"
omconfig system alertaction event=storagesysfail execappath="%ScriptPath% storage system failure"
omconfig system alertaction event=storagectrlwarn execappath="%ScriptPath% storage controller warning"
omconfig system alertaction event=storagectrlfail execappath="%ScriptPath% storage controller failure"
omconfig system alertaction event=pdiskwarn execappath="%ScriptPath% physical disk warning"
omconfig system alertaction event=pdiskfail execappath="%ScriptPath% physical disk failure"
omconfig system alertaction event=vdiskwarn execappath="%ScriptPath% virtual disk warning"
omconfig system alertaction event=vdiskfail execappath="%ScriptPath% virtual disk failure"
omconfig system alertaction event=enclosurewarn execappath="%ScriptPath% enclosure warning"
omconfig system alertaction event=enclosurefail execappath="%ScriptPath% enclosure failure"
omconfig system alertaction event=storagectrlbatterywarn execappath="%ScriptPath% storage controller battery warning"
omconfig system alertaction event=storagectrlbatteryfail execappath="%ScriptPath% storage controller battery failure"

ECHO.
ECHO Sending sample alert to:
ECHO %ToEmail%
CALL :Alert Testing Dell hardware alert warnings...
ECHO.
PAUSE
GOTO End

:End
ENDLOCAL

Skriptänderungen/Wartung

Die Ereigniswarnungen des bereitgestellten Skripts stammen von einem unserer Dell Server. Abhängig von Ihrer Dell Server-Hardware und Server Assistant-Version können die Warnungen variieren. Im Allgemeinen können Sie beim Ausführen des Setup-Skripts feststellen, ob ein Ereignis für Ihren Server nicht gültig ist (z. B. wenn Sie keine Dell RAID-Controller haben), da einige der Elemente zum Erstellen von Speicherereignissen fehlschlagen.

Die Ereignisauslöser im obigen Skript wurden abgerufen, indem Sie Folgendes an einer Eingabeaufforderung ausführen:

omconfig-Systemwarnungsaktion /?

Dieser Befehl listet alle Ereignisschlüsselwörter mit einer Beschreibung des jeweiligen Alerts auf. Um zusätzliche Warnungen hinzuzufügen, führen Sie den obigen Befehl aus, fügen Sie die fehlenden Einträge zum Setup-Teil des Skripts hinzu und führen Sie das Skript dann mit dem Schalter /Setup erneut aus.

Links

Laden Sie das Dell Server-E-Mail-Warnungsskript von SysadminGeek.com herunter

Blat Command Line E-Mailer herunterladen

Dell Support-Website



Schreibe einen Kommentar

Deine E-Mail-Adresse wird nicht veröffentlicht. Erforderliche Felder sind mit * markiert.

Schaltfläche "Zurück zum Anfang"